Is there any way to check BADI/BAPI/USer exits has been implemented in a tc

[Former Member]

Dear All,

Is there any way to check BADI/BAPI/USer exits that has been implemented in a tcode. For example I would like to check CJ20n. What kind of BADI/BAPI/User exists has been implemented for this tcode. Because it seems there are some enhancement in a tcode...but i am not sure how can we know...

If i know then i can documented for my knowledge if doing project later.

Cheers.

Nies

[varshal_kachole3]

Hi,

Go to Tcode CJ30-system-status-double click on programgotoatributes--copy the package.

Go to CMODutilitiesSAP Enhancementmention the package nameexecute.

hope its useful..

Reward points if useful.

thanks..

[varshal_kachole3]

hi,

to find out the user exit for any Tcode: e.g CJ30,

Please follwo the steps as below:

1. Tcode SMOD>utilities>list enhancement-->

Give the Deve. class of the characteristics and check the display components and execute.

2. In case Dev class is unknown for CJ30, the Tcode: CJ30>system>status>double click the program>and then go to atributes..

Hope it helps.

Reward points if helpful.

thanks...

[Former Member]

Hi Varshal,

I tried SMOD then go to utilities after that it only shows menu Find... cannot find list enhancement. ( I use 4.7 version)

Then,

I tried CJ30 to find dev class by run Tcode: CJ30>system>status>double click the program>and then go to atributes..

But i cannot find any dev class .

Am i missing something.

Cheers,

Nies

[former_member189059]

Hello Nies,

This is the code (available in other places on sdn) to find user exits in a tcode and it shows in green if they are implemented

However, it doesn't seem to show anything for CJ20N

*&---------------------------------------------------------------------*
*& Report  Z_FINDEXIT
*&
*&---------------------------------------------------------------------*
*&    Finding the user-exits of a SAP transaction code
*&
*&---------------------------------------------------------------------*

REPORT  z_findexit NO STANDARD PAGE HEADING.

INCLUDE <icon>.

TABLES : tstc, tadir, modsapt, modact, trdir, tfdir, enlfdir.
TABLES : tstct, modsap , tftit , modattr.

DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.
DATA : field1(30).
DATA : v_devclass LIKE tadir-devclass.
DATA : v_text(10).

PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.

START-OF-SELECTION.

  SELECT SINGLE * FROM tstc WHERE tcode EQ p_tcode.

  IF sy-subrc EQ 0.
    SELECT SINGLE * FROM tadir WHERE pgmid = 'R3TR'
                    AND object = 'PROG'
                    AND obj_name = tstc-pgmna.
    MOVE : tadir-devclass TO v_devclass.
    IF sy-subrc NE 0.
      SELECT SINGLE * FROM trdir WHERE name = tstc-pgmna.
      IF trdir-subc EQ 'F'.
        SELECT SINGLE * FROM tfdir WHERE pname = tstc-pgmna.
        SELECT SINGLE * FROM enlfdir WHERE funcname =  tfdir-funcname.
        SELECT SINGLE * FROM tadir WHERE pgmid = 'R3TR'
                                     AND object = 'FUGR'
                                     AND obj_name EQ enlfdir-area.

        MOVE : tadir-devclass TO v_devclass.
      ENDIF.
    ENDIF.

    SELECT * FROM tadir INTO TABLE jtab
                          WHERE pgmid = 'R3TR'
                            AND object = 'SMOD'
                            AND devclass = v_devclass.
    SELECT SINGLE * FROM tstct WHERE sprsl EQ sy-langu AND
                                     tcode EQ p_tcode.
    FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
    WRITE:/(19) 'Transaction Code - ',
         20(10) p_tcode,
         35(50) tstct-ttext.
    SKIP.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED OFF.
    WRITE : /3 'E - Function Exit',
            25 'S - Screen Exit',
            45 'T - Table Exit',
            64 'C -  GUI Code',
            103 space.
    FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
    WRITE : /3 icon_activate AS ICON,
             5 ' - Part of Active Project',
            31 icon_deactivate AS ICON,
            33 ' - Part of Deativated Project',
            63 'SPACE' ,
            69 '- Not Assignment to Project',
            103 space.


    IF NOT jtab[] IS INITIAL.
      WRITE:/(103) sy-uline.
      FORMAT COLOR COL_HEADING INTENSIFIED ON.
      WRITE:/1 sy-vline,
             2 'Exit Name',
            13 sy-vline ,
            14 'Description',
            75  sy-vline,
            79 sy-vline,
            82 'E',
            84 sy-vline,
            86 'S',
            89 sy-vline,
            91 'T',
            94 sy-vline,
            96 'C',
            99 sy-vline,
            103 sy-vline.

      WRITE:/(103) sy-uline.
      LOOP AT jtab.
        SELECT SINGLE * FROM modsapt
                   WHERE sprsl = sy-langu AND
                          name = jtab-obj_name.
        FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
        WRITE:/1 sy-vline,
             2(10) jtab-obj_name HOTSPOT ON,
             13 sy-vline ,
             14 modsapt-modtext,
             75 sy-vline,
             76 icon_information AS ICON HOTSPOT ON,
             79 sy-vline.

        SELECT SINGLE * FROM modsap
                 WHERE name = jtab-obj_name
                 AND typ = 'E'.
        IF sy-subrc = 0.
          WRITE : 80 icon_green_light AS ICON.
        ELSE.
          WRITE : 80 icon_red_light AS ICON.
        ENDIF.
        WRITE : 84 sy-vline.
        SELECT SINGLE * FROM modsap
                 WHERE name = jtab-obj_name
                 AND typ = 'S'.
        IF sy-subrc = 0.
          WRITE : 85 icon_green_light AS ICON.
        ELSE.
          WRITE : 85 icon_red_light AS ICON.
        ENDIF.
        WRITE : 89 sy-vline.
        SELECT SINGLE * FROM modsap
                 WHERE name = jtab-obj_name
                 AND typ = 'T'.
        IF sy-subrc = 0.
          WRITE : 90 icon_green_light AS ICON.
        ELSE.
          WRITE : 90 icon_red_light AS ICON.
        ENDIF.
        WRITE : 94 sy-vline.
        SELECT SINGLE * FROM modsap
                 WHERE name = jtab-obj_name
                 AND typ = 'C'.
        IF sy-subrc = 0.
          WRITE : 95 icon_green_light AS ICON.
        ELSE.
          WRITE : 95 icon_red_light AS ICON.
        ENDIF.
        WRITE : 99 sy-vline.
        SELECT SINGLE * FROM modact
                        WHERE  member = jtab-obj_name.
        IF sy-subrc = 0.
          SELECT SINGLE * FROM modattr
                          WHERE name = modact-name.
          IF modattr-status = 'A'.
            WRITE : 100 icon_activate AS ICON.
          ELSE.
            WRITE : 100 icon_deactivate AS ICON.
          ENDIF.
        ENDIF.
        WRITE : 103 sy-vline.

      ENDLOOP.
      WRITE:/(103) sy-uline.
      DESCRIBE TABLE jtab.
      SKIP.
      FORMAT COLOR COL_TOTAL INTENSIFIED ON.
      WRITE:/ 'No of Exits:' , sy-tfill.
    ELSE.
      FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
      WRITE:/(95) 'No User Exit exists'.
    ENDIF.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(95) 'Transaction Code Does Not Exist'.
  ENDIF.

AT LINE-SELECTION.
  GET CURSOR FIELD field1.
  IF field1 = 'ICON_INFORMATION'.
    v_text =  sy-lisel+1(10).
    FORMAT COLOR COL_HEADING.
    WRITE sy-uline(100).
    WRITE: /1 sy-vline,
           3 v_text COLOR COL_HEADING,
           25(60) sy-lisel+13(60) COLOR COL_HEADING,
           99 space COLOR COL_HEADING,
           100 sy-vline.
    WRITE sy-uline(100).
    PERFORM display_exit_details.
  ELSE.
    CHECK field1(4) EQ 'JTAB'.
    SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).
    CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.
  ENDIF.

*& Form  display_exit_details
*&---------------------------
FORM display_exit_details .
  CLEAR modsap.
* FUnction Exits
  FORMAT COLOR COL_GROUP INTENSIFIED OFF.
  SELECT * FROM  modsap
           WHERE name = v_text
           AND   typ = 'E' .
    WRITE : /1 sy-vline,
          3(20) modsap-member.
    SELECT SINGLE * FROM tftit
                    WHERE spras = 'EN'
                    AND   funcname = modsap-member.
    WRITE : 24 sy-vline,
            25(75) tftit-stext,
            100 sy-vline .
  ENDSELECT.
  IF sy-subrc = 0.
    WRITE sy-uline(100).
  ENDIF.
  CLEAR modsap.

* Screen Exits
  FORMAT COLOR COL_KEY INTENSIFIED OFF.
  SELECT * FROM  modsap
           WHERE name = v_text
           AND   typ = 'S'.
    WRITE : /1 sy-vline,
          3 modsap-member,
          99 space,
          100 sy-vline.
  ENDSELECT.
  IF sy-subrc = 0.
    WRITE sy-uline(100).
  ENDIF.
  CLEAR modsap.

* Table Exits
  FORMAT COLOR COL_KEY INTENSIFIED OFF.
  SELECT * FROM  modsap
           WHERE name = v_text
           AND   typ = 'T'.
    WRITE : /1 sy-vline,
          3 modsap-member,
          99 space,
          100 sy-vline.
  ENDSELECT.
  IF sy-subrc = 0.
    WRITE sy-uline(100).
  ENDIF.
  CLEAR modsap.

* GUI Exits
  FORMAT COLOR COL_KEY INTENSIFIED OFF.
  SELECT * FROM  modsap
           WHERE name = v_text
           AND   typ = 'C'.
    WRITE : /1 sy-vline,
          3 modsap-member,
          99 space,
          100 sy-vline.
  ENDSELECT.
  IF sy-subrc = 0.
    WRITE sy-uline(100).
  ENDIF.
ENDFORM.                    "display_exit_details