HEre is that example program again, this time with a header and footer added to it. I hope that is what you meant by text.
REPORT zrich_0001.
TYPES: BEGIN OF t_spfli,
carrid TYPE spfli-carrid,
connid TYPE spfli-connid,
countryfr TYPE spfli-countryfr,
cityfrom TYPE spfli-cityfrom,
airpfrom TYPE spfli-airpfrom,
countryto TYPE spfli-countryto,
cityto TYPE spfli-cityto,
airpto TYPE spfli-airpto,
fltime TYPE spfli-fltime,
deptime TYPE spfli-deptime,
arrtime TYPE spfli-arrtime,
distance TYPE spfli-distance,
distid TYPE spfli-distid,
END OF t_spfli.
DATA: ispfli TYPE TABLE OF t_spfli.
DATA: gr_table TYPE REF TO cl_salv_table.
DATA: gr_functions TYPE REF TO cl_salv_functions.
DATA: gr_display TYPE REF TO cl_salv_display_settings.
DATA: gr_columns TYPE REF TO cl_salv_columns_table.
DATA: gr_column TYPE REF TO cl_salv_column_table.
DATA: gr_sorts TYPE REF TO cl_salv_sorts.
DATA: gr_agg TYPE REF TO cl_salv_aggregations.
START-OF-SELECTION.
SELECT * INTO CORRESPONDING FIELDS OF TABLE ispfli FROM spfli.
cl_salv_table=>factory( IMPORTING r_salv_table = gr_table
CHANGING t_table = ispfli ).
gr_functions = gr_table->get_functions( ).
gr_functions->set_all( abap_true ).
gr_columns = gr_table->get_columns( ).
gr_column ?= gr_columns->get_column( 'DISTANCE' ).
gr_column->set_quantity_column( 'DISTID' ).
gr_sorts = gr_table->get_sorts( ).
gr_sorts->add_sort( columnname = 'CITYTO' subtotal = abap_true ).
gr_agg = gr_table->get_aggregations( ).
gr_agg->add_aggregation( 'DISTANCE' ).
PERFORM build_header.
PERFORM build_footer.
gr_table->display( ).
*&---------------------------------------------------------------------*
*& Form build_header
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* --> p1 text
* <-- p2 text
*----------------------------------------------------------------------*
FORM build_header .
* Set the top of list
DATA: lr_grid TYPE REF TO cl_salv_form_layout_grid,
lr_gridx TYPE REF TO cl_salv_form_layout_grid,
lr_flow TYPE REF TO cl_salv_form_layout_flow,
lr_pict TYPE REF TO cl_salv_form_picture,
lr_logo TYPE REF TO cl_salv_form_layout_logo,
lr_label TYPE REF TO cl_salv_form_label,
lr_text TYPE REF TO cl_salv_form_text.
CREATE OBJECT lr_grid.
lr_grid->create_header_information( row = 1 column = 1
text = sy-title
tooltip = sy-title ).
lr_gridx = lr_grid->create_grid( row = 2 column = 1 ).
lr_label = lr_gridx->create_label( row = 3 column = 1
text = 'Run Date:' tooltip = 'Run Date' ).
lr_text = lr_gridx->create_text( row = 3 column = 2
text = sy-datum tooltip = sy-datum ).
lr_label = lr_gridx->create_label( row = 4 column = 1
text = 'Run Time:' tooltip = 'Run Time' ).
lr_text = lr_gridx->create_text( row = 4 column = 2
text = sy-uzeit tooltip = sy-uzeit ).
* Create logo layout, set grid content on left and logo image on right
CREATE OBJECT lr_logo.
lr_logo->set_left_content( lr_grid ).
lr_logo->set_right_logo( 'ENJOYSAP_LOGO' ).
* Set the element top_of_list
gr_table->set_top_of_list( lr_logo ).
ENDFORM. " build_header
*&---------------------------------------------------------------------*
*& Form build_footer
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM build_footer.
DATA: lr_grid TYPE REF TO cl_salv_form_layout_grid,
lr_label TYPE REF TO cl_salv_form_label,
lr_text TYPE REF TO cl_salv_form_text.
CREATE OBJECT lr_grid.
* Show User name
lr_label = lr_grid->create_label( row = 1 column = 1
text = 'User Id:' tooltip = 'User Id' ).
lr_text = lr_grid->create_text( row = 1 column = 2
text = sy-uname tooltip = sy-uname ).
* Set the element end_of_list
gr_table->set_end_of_list( lr_grid ).
ENDFORM. "build_footer
Regards,
Rich Heilman
- SAP Managed Tags:
