Roadmap UI element problem

[Former Member]

Hi,

I'm facing a problem with highlighting the roadmap step, while using the RoadMap UI element. How do I get to get the active roadmap step to display in a highlighted (yellow) colour?

I'm using the MultipleRoadMapStep (the one used for dynamic programming). The documentation didn't throw light into this.

Please help.

Regards,

Adithya

[Former Member · Accepted solution]

Hi Adithya,

Check for the standard example WDR_TEST_UI_ELEMENTS and WDR_TEST_EVENTS. This has detailed information about all the events of this particular UI element.

Hope this will help!

Cheers,

Darshna.

[Former Member · Accepted solution]

Hi Darshana, Parry,

Thanks for your replies. My problem is specific to dynamic roadmap generation.

I am able to get the entire roadmap rendered as per requirement with all other expected behaviour but for the fact that the selected step does not get highlighted in yellow.

Any tips on what I'm missing out? (the demo examples don't help me).

Thanks.

Best Regards,

Adithya

[shwetars · Accepted solution]

Hello Adithya,

You have missed out on one step, you need to set the value of the roadmap ui-element property selectedStep everytime a roadmap step is clicked.

Create a context attribute of type string and bind the property to it. Everytime a roadmap step is clicked the event onSelect is triggered, within the handler one of the importing parameters is 'step', just set this value to the above context attribute apart from doing other event handling.

Regards,

Shweta

[shwetars · Accepted solution]

hi Adithya,

I tried out the dynamic roadmap creation and it works perfectly fine.

i have two static views v_step1 and v_step2, there is context node 'roadmap' under which i have an attribute 'selected_step' of type string. there is an action handler 'load' within which i just fire plugs based on step selected.

Following is the sample code for dynamic roadmap creation:

DATA: lo_roadmap TYPE REF TO cl_wd_road_map,

lo_roadmap_step TYPE REF TO cl_wd_road_map_step,

lo_view_cont_elem TYPE REF TO cl_wd_view_container_uielement,

lo_root TYPE REF TO cl_wd_uielement_container.

lo_root ?= wd_comp_controller->mr_view->get_root_element( ).

CALL METHOD cl_wd_road_map=>new_road_map

EXPORTING

bind_selected_step = 'ROADMAP.SELECTED_STEP'

id = 'ROADMAP'

on_select = 'LOAD'

view = wd_comp_controller->mr_view

RECEIVING

control = lo_roadmap.

cl_wd_matrix_head_data=>new_matrix_head_data( lo_roadmap ).

CALL METHOD lo_root->add_child

EXPORTING

the_child = lo_roadmap.

CALL METHOD cl_wd_road_map_step=>new_road_map_step

EXPORTING

id = 'STEP1'

name = 'STEP1'

RECEIVING

control = lo_roadmap_step.

CALL METHOD lo_roadmap->add_step

EXPORTING

the_step = lo_roadmap_step.

CALL METHOD cl_wd_road_map_step=>new_road_map_step

EXPORTING

id = 'STEP2'

name = 'STEP2'

RECEIVING

control = lo_roadmap_step.

CALL METHOD lo_roadmap->add_step

EXPORTING

the_step = lo_roadmap_step.

CALL METHOD cl_wd_view_container_uielement=>new_view_container_uielement

EXPORTING

id = 'VC1'

view = wd_comp_controller->mr_view

RECEIVING

control = lo_view_cont_elem.

cl_wd_matrix_head_data=>new_matrix_head_data( lo_view_cont_elem ).

CALL METHOD lo_root->add_child

EXPORTING

the_child = lo_view_cont_elem.

DATA: lo_api_v_test TYPE REF TO if_wd_view_controller,

lo_comp_usage TYPE REF TO if_wd_component_usage.

lo_api_v_test = wd_this->wd_get_api( ).

CALL METHOD lo_api_v_test->prepare_dynamic_navigation

EXPORTING

source_window_name = 'W_MAIN'

source_vusage_name = 'V_TEST_USAGE_1'

source_plug_name = 'TO_EMPTY'

target_view_name = 'EMPTYVIEW'

target_plug_name = 'FRM_MAIN'

target_embedding_position = 'V_TEST/VC1'

RECEIVING

component_usage = lo_comp_usage.

CALL METHOD lo_api_v_test->prepare_dynamic_navigation

EXPORTING

source_window_name = 'W_MAIN'

source_vusage_name = 'V_TEST_USAGE_1'

source_plug_name = 'TO_STEP1'

target_view_name = 'V_STEP1'

target_plug_name = 'FRM_MAIN'

target_embedding_position = 'V_TEST/VC1'

RECEIVING

component_usage = lo_comp_usage.

CALL METHOD lo_api_v_test->prepare_dynamic_navigation

EXPORTING

source_window_name = 'W_MAIN'

source_vusage_name = 'V_TEST_USAGE_1'

source_plug_name = 'TO_STEP2'

target_view_name = 'V_STEP2'

target_plug_name = 'FRM_MAIN'

target_embedding_position = 'V_TEST/VC1'

RECEIVING

component_usage = lo_comp_usage.

Regards,

Shweta

[Former Member · Accepted solution]

Hi Shwetha,

This solved my problem.Thanks very much for your help.

Best regards,

Adi

[Former Member]

Please refer to Component WDR_TEST_EVENTS >> View ROADMAP.

Cheers

Parry