on 06-24-2015 10:44 AM
Hi Experts,
Could you please let me know how to make a check box values checked by default on advanced search of SC for following fields?
1) Show only team shopping cart
2) Include completed shopping cart.
Whenever we go to advanced search screen and select a search for SC then check box for above two fields should be checked by default.
PFA screen shots for your reference.
Hi,
you can create an enhancement for Web Dynpro Component /SAPSRM/WDC_UI_DS_SO_SC, View V_SC_SYSTEM_DTLS. To this enhancement you can add a Post-Exit for Method WDDOMODIFYVIEW and here the following Code would default the indicators to be ticked:
METHOD _pst_dkdjyd7xx46x1kozj49qzys59 . "Exit of WDDOMODIFYVIEW (in Z... )
DATA lo_nd_search_sc TYPE REF TO if_wd_context_node.
DATA lo_el_search_sc TYPE REF TO if_wd_context_element.
DATA ls_search_sc TYPE wd_this->element_search_sc.
DATA lv_showonlyteamcarts TYPE wd_this->element_search_sc-showonlyteamcarts.
DATA lv_with_closed TYPE wd_this->element_search_sc-with_closed.
* --- Execute only when called for the first time
IF first_time = abap_true.
* --- Get Context Node
lo_nd_search_sc = wd_context->path_get_node( path = `SEARCH.SEARCH_SC` ).
IF lo_nd_search_sc IS BOUND.
* --- Get Element of node
lo_el_search_sc = lo_nd_search_sc->get_element( ).
IF lo_el_search_sc IS BOUND.
* --- Set default value for "Show only Team Carts"
lv_showonlyteamcarts = abap_true.
lo_el_search_sc->set_attribute(
name = `SHOWONLYTEAMCARTS`
value = lv_showonlyteamcarts ).
* --- Set default value for "Include completed Shopping Carts"
lv_with_closed = abap_true.
lo_el_search_sc->set_attribute(
name = `WITH_CLOSED`
value = lv_with_closed ).
ENDIF.
ENDIF.
ENDIF.
ENDMETHOD.
Regards
Oliver
You must be a registered user to add a comment. If you've already registered, sign in. Otherwise, register and sign in.
You must be a registered user to add a comment. If you've already registered, sign in. Otherwise, register and sign in.