oops consept in abap

Former Member · ‎01-14-2007

hi

i just want to know abt oops consept usage in abap...

Former Member · ‎01-14-2007

Hi,

You can read the book called as ABAP Objects. It is a very good book. You will also get miniSAP CD's along with this book.

You will get lots of material related to ABAP Objects on SDN also. Just type ABAP Objects in the search on SDN. It gives lots of useful links. Also, check out : https://www.sdn.sap.com/irj/sdn/go/portal/prtroot/docs/library/uuid/0a33479c-0b01-0010-7485-dc8c09d6...

Reward points if the answer is helpful.

Regards,

Mukul

Former Member · ‎01-16-2007

Hi,

The object-oriented approach, however, focuses on objects that represent abstract or concrete things of the real world. These objects are first defined by their character and their properties which are represented by their internal structure and their attributes (data). The behaviour of these objects is described by methods (functionality).

Just have a look at these links;

<a href="http://java.sun.com/docs/books/tutorial/java/concepts/">http://java.sun.com/docs/books/tutorial/java/concepts/</a>

Regards,

Gunasree.

uwe_schieferstein · ‎01-17-2007

Hello Venkat

The following sample report shows the advantage of OO-concepts over classical programming. The report executes completely different functions depending on the selected company code yet the coding in the main program (between START-OF-SELECTION and END-OF-SELECTION) remains the same.

If a new company code with new functionality has to be added you simply extend the factory method LCL_BUKRS=>CREATE and create a new implementing class for this company code. NO changes whatsoever in the main program.

*&---------------------------------------------------------------------*
*& Report  ZUS_SDN_ABAP_OO_CONCEPTS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  zus_sdn_abap_oo_concepts.



*CLASS lcl_bukrs_1000 DEFINITION DEFERRED.
*CLASS lcl_bukrs_2000 DEFINITION DEFERRED.
*CLASS lcl_bukrs_3000 DEFINITION DEFERRED.

*---------------------------------------------------------------------*
*       INTERFACE lif_bukrs
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
INTERFACE lif_bukrs.

  .
    DATA:
      md_bukrs    TYPE bukrs.

    METHODS:
      process_data.



  ENDINTERFACE.                    "lif_bukrs



*---------------------------------------------------------------------*
*       CLASS lcl_bukrs DEFINITION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs DEFINITION .

PUBLIC SECTION.

  TYPE-POOLS: abap.

  INTERFACES lif_bukrs.

  CLASS-METHODS:
    create
      IMPORTING
        value(id_bukrs)     TYPE bukrs
      RETURNING
        value(ro_instance)  TYPE REF TO lif_bukrs.



ENDCLASS.                    "lcl_bukrs DEFINITION

*---------------------------------------------------------------------*
*       CLASS lcl_bukrs IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs IMPLEMENTATION.




* Factory method
  METHOD create.
*   define local data
    DATA:
      ld_class(30)    TYPE c.

    CHECK ( cl_reexc_company_code=>exists( id_bukrs ) = abap_true ).

    CONCATENATE 'LCL_BUKRS' id_bukrs INTO ld_class
      SEPARATED BY '_'.
    CONDENSE ld_class NO-GAPS.

    CASE id_bukrs.
      WHEN '1000'.
        CREATE OBJECT ro_instance TYPE (ld_class).

      WHEN '2000'.
        CREATE OBJECT ro_instance TYPE (ld_class).

      WHEN '3000'.
        CREATE OBJECT ro_instance TYPE (ld_class).

      WHEN OTHERS.
    ENDCASE.

    IF ( ro_instance IS BOUND ).
      ro_instance->md_bukrs = id_bukrs.
    ENDIF.

  ENDMETHOD.                    "create


  METHOD lif_bukrs~process_data.
*     no implementation in factory class
  ENDMETHOD.                    "process_data


ENDCLASS.                    "lcl_bukrs IMPLEMENTATION



*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_1000
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_1000 DEFINITION.


  PUBLIC SECTION.
    INTERFACES lif_bukrs.

ENDCLASS.                    "lcl_bukrs_1000  INHERITING FRO


*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_1000 IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_1000 IMPLEMENTATION.

  METHOD lif_bukrs~process_data.
*   define local data
    DATA:
      ld_msg    TYPE bapi_msg.

    CONCATENATE 'Company Code' lif_bukrs~md_bukrs
      INTO ld_msg SEPARATED BY ' = '.
    MESSAGE ld_msg TYPE 'I'.
  ENDMETHOD.                    "process_data
ENDCLASS.                    "lcl_bukrs_1000 IMPLEMENTATION


*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_2000
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_2000 DEFINITION.


  PUBLIC SECTION.
    INTERFACES lif_bukrs.

ENDCLASS.                    "lcl_bukrs_2000  INHERITING FRO


*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_2000 IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_2000 IMPLEMENTATION.

  METHOD lif_bukrs~process_data.
*   define local data
    DATA:
      lt_knb1    TYPE STANDARD TABLE OF knb1,
      lo_table   TYPE REF TO cl_salv_table.

    SELECT * FROM knb1 INTO TABLE lt_knb1
      WHERE bukrs = lif_bukrs~md_bukrs.

    TRY.
        CALL METHOD cl_salv_table=>factory
          IMPORTING
            r_salv_table = lo_table
          CHANGING
            t_table      = lt_knb1.
        lo_table->display( ).
      CATCH cx_salv_msg .
    ENDTRY.
  ENDMETHOD.                    "process_data
ENDCLASS.                    "lcl_bukrs_2000 IMPLEMENTATION


*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_3000
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_3000 DEFINITION.


  PUBLIC SECTION.
    INTERFACES lif_bukrs.

ENDCLASS.                    "lcl_bukrs_3000  INHERITING FRO


*---------------------------------------------------------------------*
*       CLASS lcl_bukrs_3000 IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_bukrs_3000 IMPLEMENTATION.

  METHOD lif_bukrs~process_data.
    CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
      EXPORTING
        action    = 'S'
        view_name = 'V_T001'
      EXCEPTIONS
        OTHERS    = 15.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.

  ENDMETHOD.                    "process_data
ENDCLASS.                    "lcl_bukrs_3000 IMPLEMENTATION



PARAMETER:
  p_bukrs      TYPE bukrs  DEFAULT '1000'.


DATA:
  gif_bukrs    TYPE REF TO lif_bukrs.

<b>START-OF-SELECTION.</b>

  gif_bukrs = lcl_bukrs=>create( p_bukrs ).
  IF ( gif_bukrs IS NOT BOUND ).
    MESSAGE 'No implementation found' TYPE 'S'.
    RETURN.
  ENDIF.

* NOTE: Coding in main program remains the same yet the
*       function executed depends on selected company code
  gif_bukrs->process_data( ).

<b>END-OF-SELECTION.</b>

Regards

Uwe