Missing gn_get_global_key

[Former Member]

Hello all,

I'm not able to find program gn_get_global_key (infocube 0IC_03, update rules from 2LIS_03_BX,BF)

It says program doesn't exist.

Does anybody have an idea where to get it?

THX

[anna_hollena]

Hello Jiri,

thus this is an old thread I sill want to answer as I had the same questions and this post is ranked high.

The routine you will find in include RSBCTGN_UPDATE_RULES.

Here is the coding:

form  gn_get_global_key tables   p_monitor structure rsmonitor
                         using    p_source_system
                                  p_objtype
                                  p_localkey
                                  p_record_no like sy-tabix
                                  p_record_all like sy-tabix
                         changing p_global_key
                                  p_rc.
 
   data: l_source_system like rssoursystem-soursysid,
         l_object_type   like rsbwbeotyp-gn_bwbeoty,
         l_local_key     like rsgn_glob_id-localid,
         l_global_key    like rsgn_glob_id.
 
   data: l_msgtext type string,
         l_wa_monitor like p_monitor.
 
   l_source_system = p_source_system.
   l_object_type = p_objtype.
   l_local_key = p_localkey.
   call function 'RS_BCT_GN_GET_GLOBAL_KEY'
     exporting
       i_source_system         = l_source_system
       i_object_type           = l_object_type
       i_local_key             = l_local_key
     importing
       e_global_key            = l_global_key
     exceptions
       source_system_not_found = 1
       object_type_not_found   = 2
       others                  = 3.
 
 
   p_rc = sy-subrc.
   p_global_key = l_global_key.
   if sy-subrc <> 0.
     case sy-subrc.
       when 1.
 *       source system not found
         message e010(rsbctgn)
           with  l_source_system p_record_no into l_msgtext.
       when 2.
 *       object type not found
         message e020(rsbctgn)
           with  l_object_type   p_record_no into l_msgtext.
       when 3.
 *       other error
         message e030(rsbctgn)
           with l_source_system l_object_type l_local_key p_record_no
               into l_msgtext.
     endcase.
     move-corresponding syst to l_wa_monitor.
     append l_wa_monitor to p_monitor.
     clear p_global_key.
   endif.
 
 endform.