Text elements for implicit Enhancement point

[Former Member]

Hi All,

Can you please guide me where text elements for an implicit enhancement point can be maintained?

Thanks.

[Former Member]

Hi,

You can maimtain the TEXT ELEMENTS in implicit enhancments in the normal way.

But you have to include those objects in the TRANSPORT REQUEST manually.

Program ID : LIMU

bject type : REPO or REPT

Regards

HM

[former_member223537]

Hi,

Since its a standard SAP program, it wont be possible to add text elements. Instead you will have to define constants & use it in your enhancement.

If you are facing issue for maintaining selection screen text inside a enhancement, then in that case you need to declare a variable & assign the text to the variable.

SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) gv_title.
PARAMETERS: p_werks TYPE char4.
SELECTION-SCREEN END OF LINE.

AT SELECTION-SCREEN OUTPUT. " Or at INITIALIZATION event
gv_title = 'Enter Plant'.     "Give the selection screen text here

Thanks,

Best regards,

Prashant

[Former Member]

Hi,

I Implemented Code in Enhancement Spot, I added One Field in standard Selection Screen using Enhancement spot for MRRL Transaction, But I am not able to maintain Selection Text for that Field It is showing in Selection Screen P_XBLNR Like. If i tried using goto --> Text Elements --> Selection Texts it is asking Key.

Can any one help me how to maintain Selection Text for Standard Program using Enhancement Spot .

Thank You,

Nagaphani

[TMNielsen]

Hi

1. Make your parameter or select-options with ref. to a data element.
2. Implement code below as enhancement to INITIALIZATION

(replace DC_BISMT and BISMT with parameter and dataelement from your own example):

(sorry for the strange table structure of the code -

like anything else in the new SDN also the "editor" is poor)

DATA:	zz_lt_sel_dtel  TYPE  rsseldtel OCCURS 0,
	zz_ls_sel_dtel  TYPE  rsseldtel.

Clear zz_lt_sel_dtel.

	zz_ls_sel_dtel-name = 'DC_BISMT'.	" Feldname
	zz_ls_sel_dtel-kind = 'S'.	" S für select-options
	zz_ls_sel_dtel-datenelment = 'BiSMT'.	" Datenelement
	APPEND zz_ls_sel_dtel TO zz_lt_sel_dtel.
	CALL FUNCTION 'SELECTION_TEXTS_MODIFY_DTEL'
	EXPORTING
	program	= sy-repid
	TABLES
	sel_dtel	= zz_lt_sel_dtel
	EXCEPTIONS
	program_not_found	= 1
	program_cannot_be_generated = 2
	OTHERS	= 3.
	IF sy-subrc <> 0.

* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO

*	WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
	ENDIF.

[TMNielsen]

By implementing my solution the translation will be handled via the data element.

[alexanderaigner]

This works great, thanks!

Here a version for some newer ABAP Systems:

data: gt_sel_dtel TYPE STANDARD TABLE OF rsseldtel.
     
" S = Select Option
" P = Parameter
  gt_sel_dtel = value #(
      ( name = 'PARAMETERNAME' kind = 'S' datenelment = 'ELEMENT' )
      ( name = 'PARAMETERNAME' kind = 'S' datenelment = 'ELEMENT' )
      ( name = 'PARAMETERNAME' kind = 'S' datenelment = 'ELEMENT' )
    ).
 
  CALL FUNCTION 'SELECTION_TEXTS_MODIFY_DTEL'
    EXPORTING
      program = sy-repid
    TABLES
      sel_dtel = gt_sel_dtel
    EXCEPTIONS
      program_not_found = 1
      program_cannot_be_generated = 2
      OTHERS = 3.
 
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*   WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.