selection-screen radio-button

[Former Member]

Hi i want to create a radio button that should come into middle of the screen.

and same time in default i want following structure how can i achieve that.

radioboton (memo) 3 side of that 3 square box

will come seprated by /

regards

Manish.

[former_member181962]

YOu can go for selection-screen layout design using a

skip statements and

SELECTION-SCREEN POSITION pos.

Effect

The next object on the current line (parameter, comment, pushbutton or underline) is positioned at pos.

You may only use this variant between SELECTION-SCREEN BEGIN OF LINE und SELECTION-SCREEN END OF LINE.

You can specify the position pos as a number (relative to the box) if you use the statement between the SELECTION-SCREEN BEGIN OF BLOCK ... WITH FRAME ... and SELECTION-SCREEN END OF BLOCK ... statements. You can also use the symbolic positions POS_LOW and POS_HIGH. These are the positions on the screen at which the system places the input fields for SELECT-OPTIONS. (POS_LOW is also the screen position for PARAMETERS).

Regards,

Ravi

[RichHeilman]

Here is a sample. You will need to create the text symbols and enter you text for them/

report zrich_0001.


selection-screen begin of line.
selection-screen position 40.
selection-screen comment (20) text-001.
selection-screen position 65.
parameters: p_rad1 radiobutton group grp1 default 'X'.
selection-screen end of line.
selection-screen begin of line.
selection-screen position 40.
selection-screen comment (20) text-002.
selection-screen position 65.
parameters: p_rad2 radiobutton group grp1.
selection-screen end of line.
selection-screen begin of line.
selection-screen position 40.
selection-screen comment (20) text-003.
selection-screen position 65.
parameters: p_rad3 radiobutton group grp1.
selection-screen end of line.

Regards,

Rich Heilman

[Former Member]

Hi,

how can i put the 3 squre box after that in between the box they are seprated by /.

after radio button square box1 / box2 / box3

[RichHeilman]

What kind of box?

Regards,

Rich Heilman

[former_member188685]

Hi,

Try this code...

with the help of position..

REPORT  Z_TEST_RADIO                            .

SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME TITLE TEXT-001.
*-For weekly
SELECTION-SCREEN BEGIN OF LINE.
<b>selection-screen position 61.</b>
PARAMETERS: PR_WEEK RADIOBUTTON GROUP RAD1 DEFAULT 'X'.
SELECTION-SCREEN COMMENT 50(11) text-010.
SELECTION-SCREEN END OF LINE.

*-For daily
SELECTION-SCREEN BEGIN OF LINE.
selection-screen position 61.
PARAMETERS: PR_DAY RADIOBUTTON GROUP RAD1.
SELECTION-SCREEN COMMENT 50(11) text-010.
SELECTION-SCREEN END OF LINE.

SELECTION-SCREEN SKIP.

PARAMETERS: PX_TOT AS CHECKBOX,    "Display Totals
            PX_SEL AS CHECKBOX,    "Show Selection Criteria
            PX_DOWN AS CHECKBOX USER-COMMAND DOWN.   "download the data
PARAMETERS: P_FILE(120) LOWER CASE,
            P_TYPE(5) AS LISTBOX VISIBLE LENGTH 5 DEFAULT 'TXT'.
PARAMETERS: P_APPL RADIOBUTTON GROUP G1,
            P_PRES RADIOBUTTON GROUP G1.
SELECTION-SCREEN END OF BLOCK B1.

Regards

vijay

[Former Member]

hii

chk this code

SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME.

SELECT-OPTIONS: S_VBELN FOR VBAK-VBELN.

PARAMETERS: P_VBTYP LIKE VBAK-VBTYP DEFAULT 'C'.

SELECTION-SCREEN END OF BLOCK B1.

SELECTION-SCREEN BEGIN OF BLOCK B2 WITH FRAME.

PARAMETERS: LIST RADIOBUTTON GROUP G1,

GRID RADIOBUTTON GROUP G1.

SELECTION-SCREEN END OF BLOCK B2.

Regards

Naresh

[rahulkavuri]

SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME TITLE TEXT-001.

SELECT-OPTIONS: S_LIFNR FOR LFA1-LIFNR, "ACCOUNT NUMBER
                S_BUKRS FOR LFB1-BUKRS, "COMPANY CODE
                S_EKORG FOR LFM1-EKORG, "PURCHASING ORG
                S_KTOKK FOR LFA1-KTOKK. "ACCOUNT GROUP

SELECTION-SCREEN END OF BLOCK B1.

SELECTION-SCREEN BEGIN OF BLOCK B2 WITH FRAME TITLE TEXT-002.

PARAMETERS: LIST RADIOBUTTON GROUP G1, "ALV LIST DISPLAY
            GRID RADIOBUTTON GROUP G1. "ALV GRID DISPLAY

SELECTION-SCREEN END OF BLOCK B2.

Now use POS_high and POS_LOW to position the radio buttons

[Former Member]

Hii Manish

copy and paste Rich's code

In the GOto -> text elements - >selection texts

Give text-001 as blank

text-002 as /

text-003 as blank

text-004 as /

text-005 as blank

text-006 as /

i guess this will work

Regards

Naresh

[RichHeilman]

Do you mean something like this?

report zrich_0001.





selection-screen begin of line.
selection-screen position 30.
parameters: p_rad1 radiobutton group grp1 default 'X'.
selection-screen comment (13) txt1.
selection-screen position 45.
selection-screen comment (13) txt2.
selection-screen position 60.
selection-screen comment (13) txt3.
selection-screen end of line.

selection-screen begin of line.
selection-screen position 30.
parameters: p_rad2 radiobutton group grp1.
selection-screen comment (13) txt4.
selection-screen position 45.
selection-screen comment (13) txt5.
selection-screen position 60.
selection-screen comment (13) txt6.
selection-screen end of line.

initialization.

  txt1 = 'Test A      /'.
  txt2 = 'Test B      /'.
  txt3 = 'Test C'.


  txt4 = 'Test D      /'.
  txt5 = 'Test E      /'.
  txt6 = 'Test F'.

Regards,

Rich Heilman

[Former Member]

Hi rich,

Similar to this which is coming on first row of the screen

after radio button test will be ther and after that

i required theree parameter sort of box..which is saprated by /

where user can enter the credit memo invoice ref...

thanks for your help....

[RichHeilman]

Ok, how about something like this.

report zrich_0001.





selection-screen begin of line.
selection-screen position 30.
parameters: p_rad1 radiobutton group grp1 default 'X'.
selection-screen position 33.
parameters: p_field1(10) type c.
selection-screen comment (1) txt1.
selection-screen position 50.
parameters: p_field2(10) type c.
selection-screen comment (1) txt2.
selection-screen position 65.
parameters: p_field3(10) type c.
selection-screen end of line.

selection-screen begin of line.
selection-screen position 30.
parameters: p_rad2 radiobutton group grp1 .
selection-screen position 33.
parameters: p_field4(10) type c.
selection-screen comment (1) txt3.
selection-screen position 50.
parameters: p_field5(10) type c.
selection-screen comment (1) txt4.
selection-screen position 65.
parameters: p_field6(10) type c.
selection-screen end of line.

initialization.

txt1 = '/'.
txt2 = '/'.
txt3 = '/'.
txt4 = '/'.

Regards,

Rich Heilman

[Former Member]

Thanks for immidiate reply...

this is solved my problem....

i distributed the Pts ....