adobe forms in R3

[Former Member]

Dear all

we can excute adobe forms in R3 itself using (CALL FUNCTION '/1BCDWB/SM00000043') this function module.This function module creates which we are exceuting the adobe forms in SFP tranasction.

Iam having one doubt.. This function module based on client dependent .. it will change this no

(1BCDWB/SM0000004) in other client..

If any other or common function module available for adobe forms executes in R3

plz give the solution

Thaks

[Former Member · Accepted solution]

1.Call the function to get the Function module name generated from Adobe form.

FP_FUNCTION_MODULE_NAME

2.And pass the form name to the above function and get the Function name.

3.Call the FM FP_JOB_OPEN

4.Now u just call function to close the job FP_JOB_CLOSE

[Former Member]

Hi Veera,

Here is a sample adobe calling program

* Output parameter & attribute of form
  gs_outputparams-nodialog = abap_true.
  gs_outputparams-getpdf   = abap_true.
  gs_docparams-langu       = sy-langu.
  gs_docparams-fillable    = abap_true.
  gs_docparams-dynamic     = abap_true.

* Get function name of form
  TRY.
*     Get functiona name
      CALL FUNCTION 'FP_FUNCTION_MODULE_NAME'
        EXPORTING
          i_name     = p_form
        IMPORTING
          e_funcname = gs_funcname.

*   For handling exceptions
    CATCH cx_root INTO g_root.
      g_text = g_root->get_text( ).
      MESSAGE g_text TYPE 'E'.
  ENDTRY.

* Open Job
  CALL FUNCTION 'FP_JOB_OPEN'
    CHANGING
      ie_outputparams = gs_outputparams
    EXCEPTIONS
      cancel          = 1
      usage_error     = 2
      system_error    = 3
      internal_error  = 4
      OTHERS          = 5.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

      CALL FUNCTION gs_funcname
        EXPORTING
          /1bcdwb/docparams  = gs_docparams
          i_fd               = gs_fd
        IMPORTING
          /1bcdwb/formoutput = gs_formoutput
        EXCEPTIONS
          usage_error        = 1
          system_error       = 2
          internal_error     = 3
          OTHERS             = 4.

* Close Job
  CALL FUNCTION 'FP_JOB_CLOSE'
    EXCEPTIONS
      usage_error    = 1
      system_error   = 2
      internal_error = 3
      OTHERS         = 4.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.       

Regards,

Mawi

Edited by: Mawi C. Ng on May 15, 2009 9:05 AM

Edited by: Mawi C. Ng on May 15, 2009 9:05 AM

Edited by: Mawi C. Ng on May 15, 2009 9:06 AM